DLG's Correct & Export
                         Problem Solution Fix
                                 v1.2

                            June 21, 1995

Okay, after hearing how everyone (including myself) uses DLG's message
correct feature as a god-send, here is a solution I hacked together to
ensure that the filenote is re-appended to a message after being
corrected so that it will properly export.

**CHANGES**  Unlike the first release of this fix (seen in a previous
message, this version will not die if it comes across a message not
having a filenote.  It will instead create a new one using the
original sender's name and the current date/time.  Although this will
work fine for PDQ's needs, it will also create a filenote for messages
that have been imported.  No harm though I suppose :)

I also assume that this fix will only work for those who use the
[C]orrect feature from the DLG Message Menu.  I think 3rd party
programs, such as Bob Stouder's exceptional TurboRead, directly access
the dlg.library leaving the lacking of a filenote after correcting a
message.

To make the proper changes, you will need to modify your menu entry
for the [C] CORRECT function.  Change the menu entry to this:

	MenuScript: (path/file) DLGConfig:Batch/DLG_Correct.menuscr
	Overlay
	NoCLI

The rest of the options can probably stay the same.

You MUST have LIST, DATE, and FILENOTE in the C: directory, and AREXX
must be installed and running!!

Now put the following three files into the DLGConfig:Batch/ directory.
The first file, the .menuscr, can be entered while changing the menu
entry parameters.

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
~~~ FILE: DLGConfig:Batch/DLG_Correct.menuscr           ~~~
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
BATCH   DLGConfig:Batch/DLG_Correct.batch %Msg_AreaNumber %Msg_MsgNumber "%Msg_From"
BUILTIN MSG_Correct
AREXX   DLGConfig:Batch/DLG_Correct.rexx


~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
~~~ FILE: DLGConfig:Batch/DLG_Correct.batch ~~~
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
.key area,msgnum,from
.bra [
.ket ]

echo >t:dlg_correct "MSG:[area]/[msgnum].msg"
echo >>t:dlg_correct "[from]"
list >>t:dlg_correct msg:[area]/[msgnum].msg nohead


~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
~~~ FILE: DLGConfig:Batch/DLG_Correct.rexx ~~~
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
/* restore filenote to msg */
/* jon d. godfrey, re0273  */

call open(d,'T:dlg_correct',R)
  file = readln(d)
  from = readln(d)
  junk = readln(d)
  note = readln(d)

  if eof(d)=1 then do

    address command "c:date >ram:date"
    call open(a,'ram:date',R)
      data=readln(a)
    call close(a)

    parse var data dayname' 'date' 'time
    dayname = left(dayname,3)
    parse var date day'-'month'-'year
    time = left(time,5)
    newdate = dayname' 'day' 'month' 'year' 'time

    note = 'Created: 'newdate', by 'from

  end
  else do

    note = right(note,length(note)-2)

  end

call close(d)

operation = 'c:filenote '||file||' "'note'"'
address command operation
address command "c:delete >NIL: t:dlg_correct"

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

Well, I've only done about an three hour's worth of testing and it seems to
be doing what it's supposed to.  If you got any questions or improvements
to offer, please let us all know.

An archive containing this text and the three files will also be
available for FREQ under the magic name of "CORRECT" at 1:212/1005.

 --- I show a clear pattern of unpredictability.

      __
 __  ///                            InterNet: jdgodfre@slonet.org
 \\\///  Jon Godfrey                    Fido: 1:212/1005
  \XX/   Moderator, Z40_AmySale     AmigaNet: 40:409/10